Управление сервами от кнопок (для аналогового макета)

[BNSF9399]

Дело было в выходной...
Делать было нечего...
Пусть и не складно, но по теме
Накидал скетч управления тремя сервами с трех кнопок с отображением положения стрелки.
Может и было уже, но интересно было самому поиграться, да и камрад на соседнем форуме озадачился таким девайсом для своего аналогового макета. В принципе, ничего не мешает и на цифровом его использовать, но без управления от КС.
При включении - сервы выворачивает в последнее состояние (если вдруг их свернули)
"Грабли" обнаружены одни, при переводе из положения 0 (угол не важен, при любых раскладах, когда запускается поворот на увеличение угла) сначала идет небольшой отскок назад.
Как говорил один мой знакомый: "Это баг, которы вовсе не баг, потому что в скрипах все правильно".
Грешу на сервы...
Сори, комменты кривые, особенно с реверсом, но думаю мысль понятна. Смысл тот же, что у местного ServoMotion.

//подключаемые библиотеки
#include <EEPROM.h>
#include <Bounce2.h>
#include <Servo.h>

//переменные конфигурации
int servoAngles[][2]={{0,90},{0,90},{0,90}}; // углы отклонения сервоприводов {"прямо", "в бок"}
byte servoReverce[]={0,0,0}; //реверс углов сервоприводов (если в положении "прямо" угол задан во втором элементе предыдущего массива, то поставить 1.)
int servoSpeed[]={10,10,10}; //скорость вращения сервопривода. указано количество миллисекунд поаорота на 1 градус

//переменные определяюще ножки подключения
int normalLed[]={8,10,12}; //ножки подключения светодиода показывающего прямое положение стрелки
int routeLed[]={9,11,13}; //ножки подключения светодиода показывающего положение стрелки "в бок"
int servoPins[]={3,5,6}; //ножки подключения провода управления сервопривода
int buttonPins[]={2,4,7}; //ножки подключения кнопок переключения

//переменные используемые при повороте сервопривода
byte CurrentPosition[]={0,0,0}; //текущее положение сервопривода. 0=прямо, 1=в бок.
int currentAngle[]={0,0,0};//текущий угол поворота сервопривода
unsigned long nextTime[]={0,0,0};// время следующего поворота на 1 градус
unsigned long currentTime; //текущее время
byte dir;// направление поворота сервопривода

//объекты сервоприводов и антидребезка кнопок
const int servos=sizeof(servoPins)/sizeof(int);
Servo servoServos[servos];
Bounce servoBouncer[servos];

void setup() {
  for(int i=0;i<servos;i++){
    pinMode(buttonPins[i], INPUT);
    servoBouncer[i] = Bounce();
    servoBouncer[i].attach(buttonPins[i]);
    servoBouncer[i].interval(5);
    pinMode(normalLed[i], OUTPUT);
    pinMode(routeLed[i], OUTPUT);
    if(EEPROM.read(i) > 1){
      EEPROM.update(i,0);
    }
    CurrentPosition[i]=EEPROM.read(i);
    digitalWrite(normalLed[i], !CurrentPosition[i]);
    digitalWrite(routeLed[i], CurrentPosition[i]);
    servoServos[i].attach(servoPins[i]);
    if(servoReverce[i]){
      servoServos[i].write(servoAngles[i][!CurrentPosition[i]]);
      currentAngle[i]=servoAngles[i][!CurrentPosition[i]];
    }
    else {
      servoServos[i].write(servoAngles[i][CurrentPosition[i]]);
      currentAngle[i]=servoAngles[i][CurrentPosition[i]];
    }
  }
  delay(1000);
  for(int i=0;i<servos;i++){
    servoServos[i].detach();
  }
}

void loop() {
  currentTime=millis();
  for(int i=0;i<servos;i++){
    if(nextTime[i]>0 && nextTime[i]<currentTime){
      if(currentAngle[i]>=servoAngles[i][0] && currentAngle[i]<=servoAngles[i][1]){
        nextTime[i]=currentTime+servoSpeed[i];
        if(servoReverce[i]){
          dir=!CurrentPosition[i];
        }
        else {
          dir=CurrentPosition[i];
        }
        if(dir){
          currentAngle[i]++;
        }
        else {
          currentAngle[i]--;
        }
        if(servoAngles[i][1]/currentAngle[i] == 2 || servoAngles[i][1]/currentAngle[i] == 2.5 ){
          digitalWrite(normalLed[i], !CurrentPosition[i]);
          digitalWrite(routeLed[i], CurrentPosition[i]);
        }
        servoServos[i].write(currentAngle[i]);
      }
      else{
        nextTime[i]=0;
        servoServos[i].detach();
      }
    }
    if(servoBouncer[i].update()){
      if(servoBouncer[i].read()==LOW){
        CurrentPosition[i]=!CurrentPosition[i];
        EEPROM.update(i,CurrentPosition[i]);
        nextTime[i]=currentTime;
        if(servoReverce[i]){
          currentAngle[i]=servoAngles[i][CurrentPosition[i]];
        }
        else {
          currentAngle[i]=servoAngles[i][!CurrentPosition[i]];
        }
        servoServos[i].attach(servoPins[i]);
      }
    }
  }
}

Схема

Можно и Arduino Pro Mini использовать, по ногам вроде как совпадает она с Uno.
Видео работы.

[malevich]

Сообщение от BNSF9399

Накидал скетч управления тремя сервами с трех кнопок с отображением положения стрелки.
Может и было уже, но интересно было самому поиграться

То есть, была в хозяйстве плата Arduino Uno, но не было Аксессуарного декодера ServoMotion1 на 4 выхода?
Ваше решение весьма элегантно и вдобавок - экономия , так как местный стрелочный декодер стоит 1200 руб, а Arduino Uno на e-bay - почти в 4 раза меньше. Но я вот уже набрал себе нужное количество местных декодеров... И жаба не душит. Работают они неплохо.

[laba]

В качестве улучшения проекта, можно добавить режимы программирования углов поворота по кнопке. Я такое делал на модуле управления переездом. А чтобы не заморачиваться с реализацией медленного перемещения на обычных серва на стандартной библиотеке, можно использовать "медленные" сервы. Разница в цене не особая.

[kudrdima]

оффтопик

Сообщение от laba

чтобы не заморачиваться с реализацией медленного перемещения на обычных серва на стандартной библиотеке, можно использовать "медленные" сервы.

А вот аппаратная реализация замедления обычных серв. Правда в описании не сказано на сколько замедляется...

[BNSF9399]

Сообщение от malevich

была в хозяйстве плата Arduino Uno, но не было

у мня в хозяйстве все есть но камраду за безнадобностью местный декодер да КС у него нет.чтобы настроить его. а по дефолту у него скорость с углами для HO

---------- Сообщение добавлено в 20:18 ---------- Предыдущие сообщение было в 20:16 ----------

Сообщение от laba

А чтобы не заморачиваться

Проще пару цифр поменять и перезалить, чем специально сервы искать... КМК

[Alexmit]

Сообщение от BNSF9399

В принципе, ничего не мешает и на цифровом его использовать, но без управления от КС.

Если изменить скетч на управление от тумблера, то тогда и с КС можно управлять.

[BNSF9399]

Сообщение от Alexmit

Если изменить скетч на управление от тумблера, то тогда и с КС можно управлять.

Не-не... в скетче как класс отсутствует DCC какие тумблера?

[Alexmit]

Сообщение от BNSF9399

какие тумблера?

Имелось в виду управление логическими уровнями.
0 - в одну сторону, 1 - в другую.

[Qvan22]

Сообщение от BNSF9399

int servoPins[]={3,5,6}; //ножки подключения провода управления сервопривода

оффтопик

Необязательно вешать управление на пины с шим. Аппаратный шим все равно тут не используется.
Библиотека Servo.h генерирует управляющую частоту программно используя timer1.
Так что можно подключать хоть пин 2, хоть пин A2 (кроме A6 и A7).

[BNSF9399]

Сообщение от Qvan22

Аппаратный шим все равно тут не используется.

Спасибо, не знал. В примерах просто везде на ШИМ повешены сервы.

---------- Сообщение добавлено в 23:26 ---------- Предыдущие сообщение было в 23:19 ----------

Сообщение от Alexmit

Имелось в виду управление логическими уровнями.
0 - в одну сторону, 1 - в другую.

у автора ТЗ запрос был именно на кнопку и именно одну кнопку.
можно и тумблера, вместо переменной CurrentPosition считывать состояние входа тумблера.

Сообщение от Alexmit

на управление от тумблера, то тогда и с КС можно управлять.

я вот тут не смог найти взаимосвязи

если допиливать до DCC, то кнопки тут не помеха. Если стрелка перевелась по команде, меняете в переменной текущее положение и все. Дальше от кнопки все будет работать как надо. А вот с тумблерами какраз так не выйдет. Ибо обнаружив, что тумблер находится в положении "прямо", а только что с КС стрелка перевелась в бок, ее тут же вернет в прямое положение. Думаю именно по этой причине, местные декодеры работают либо от тумблеров, либо от КС.

[Alexmit]

Сообщение от BNSF9399

если допиливать до DCC,

А не надо до DCC допиливать.
Просто провода вместо тумблеров, цепляются напрямую к DCC++, например.
И ещё есть варианты.

[BNSF9399]

Сообщение от Alexmit

цепляются напрямую к DCC++

в какое место?

[Alexmit]

Сообщение от BNSF9399

в какое место?

Заходим вот сюда http://wiki.rocrail.net/doku.php?id=dccpp:dccpp-en
И ищем G-ASH02.

[BNSF9399]

Сообщение от Alexmit

Цитировать

ааа.. понял. ну в принципе, почему бы и нет.

[Andrew78]

Подскажите пожалуйста такую вещь. Замутил пока такую схему (пока тренируюсь, нажимаю левую кнопку, загорается правый диод и сервы поворачиваются в одну сторону, нажимаю правую - загорается правый диод и сервы поворачиваютчя в другую сторону). После поворота сервы часто гудят. Из за чего это может быть?

[BNSF9399]

Сообщение от Andrew78

После поворота сервы часто гудят. Из за чего это может быть?

а почему бы им не гудеть? они пытаются встать в правильное положение. чем дешевле серва - тем более выражен будет ждиттер.
после поворота нужно делать detach()

[Andrew78]

Завтра уже проверю. А delay() надо делать перед detach(), что бы сервы успели занять свое положение?

[BNSF9399]

Сообщение от Andrew78

А delay() надо делать перед detach(),

безусловно.
но я не сторонние пауз. посмотрите как это реализовано в моем скетче.
и не забудьте перед началом поворота attach сделать

[kuli]

Сообщение от BNSF9399

управления тремя сервами

День добрый.
В вопросе ардуино ничего не понимаю. Какая то тупость наподает
А если на 15 серв? Реально?

[BNSF9399]

Сообщение от kuli

А если на 15 серв? Реально?

а почему нет? возможно.
1 плата = 3 сервы
15/3 = 5 плат
и будет 15 серв

[Dampflok]

Сообщение от BNSF9399

5 плат - 15 серв

Зачем так человека пугаете!

Сообщение от kuli

День добрый.
А если на 15 серв? Реально?

И Вам тоже Доброго времени!
И на 15 серв с одной платы возможно. Только, пожалуй, не с одновременным срабатыванием.
Иначе, как говорят, "просядет" напряжение

Сообщение от kuli

В вопросе ардуино ничего не понимаю. Какая то тупость наподает

Не бойтесь!
Главная истина: не нужно быть "электронщиком" для того,
чтобы научиться играть с ардуиной и её принадлежностями (датчиками, сервомоторами и прочими компонентами)

[мистер И.К.С.]

Сообщение от BNSF9399

1 плата = 3 сервы 15/3 = 5 плат и будет 15 серв

у вас разве атмега8 ?

У старых Ардуин, укомплектованных мегой 8, имеется всего три ШИМ вывода (digital 9,10,11), у Ардуин укомплектованных мегой 168 или 328 их шесть (digital 3,5,6,9,10,11). Семейство Arduino MEGA имеет на своем борту целых 14 ШИМ выводов.

это если напрямую, а если с дополнительной платой то на каждой плате 16 штук. но не все одновременно.

[kuli]

Сообщение от BNSF9399

1 плата = 3 сервы

3 ардуины?

Сообщение от Dampflok

не с одновременным срабатыванием

естественно. А как не научите?

[kudrdima]

Сообщение от Dampflok

И на 15 серв с одной платы возможно. Только, пожалуй, не с одновременным срабатыванием.
Иначе, как говорят, "просядет" напряжение

Если Вы внимательно посмотреть на предложенный скетч, то видно, что в каждый момент времени обращение идёт лишь к одной серве, и повернув её на 1 градус, "ардуина" обращается к следующей.

[Andrew78]

Так по идее надо просто на питание серв отдельную "шину" кинуть, а не с платы ардуино брать. Главное что бы хватило самих пинов для управления сервами, кнопками и диодами.
А такое количество плат нужно потому что у УНО - 14 выходов, Если управлять одной кнопкой, то надо пин на кнопку, 2 пина на диоды, пин на серву. Итого 4 пина на серву.
В итоге 14/4 = 3.5, или 3 сервы на УНО, и 54/3 = 18 серв на Мегу.

ЗЫ. У меня 2 сервы одновременно крутились. Там по идее одномоментно пустил сигнал на поворот и приступил к следующей серве. Вечером попробую видео снять.